cmake_minimum_required(VERSION 3.25)

project(vista VERSION 0.1.0 LANGUAGES CXX)

include(GNUInstallDirs)
include(CMakePackageConfigHelpers)
include(CTest)

set(CMAKE_CXX_STANDARD 23)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

find_package(modulus CONFIG REQUIRED)
find_package(Boost CONFIG REQUIRED COMPONENTS json)
find_package(OpenCV CONFIG REQUIRED COMPONENTS core imgproc imgcodecs)

add_library(vista
  src/detail/errors.cpp
  src/capture.cpp
  src/config.cpp
  src/frame.cpp
  src/inference.cpp
  src/opencv.cpp
  src/processing.cpp
)
target_include_directories(vista PUBLIC
  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
  $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
)
target_compile_features(vista PUBLIC cxx_std_23)
target_link_libraries(vista PUBLIC
  modulus::modulus
  Boost::boost
  Boost::json
  ${OpenCV_LIBS}
)
add_library(vista::vista ALIAS vista)

if(BUILD_TESTING)
  add_subdirectory(tests)
endif()

install(TARGETS vista
  EXPORT vista-targets
  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)

install(DIRECTORY include/ DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})

install(EXPORT vista-targets
  NAMESPACE vista::
  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/vista
)

configure_package_config_file(
  ${CMAKE_CURRENT_SOURCE_DIR}/cmake/vista_config.cmake.in
  ${CMAKE_CURRENT_BINARY_DIR}/vista-config.cmake
  INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/vista
)

write_basic_package_version_file(
  ${CMAKE_CURRENT_BINARY_DIR}/vista-config-version.cmake
  VERSION ${PROJECT_VERSION}
  COMPATIBILITY SameMajorVersion
)

install(FILES
  ${CMAKE_CURRENT_BINARY_DIR}/vista-config.cmake
  ${CMAKE_CURRENT_BINARY_DIR}/vista-config-version.cmake
  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/vista
)
