cmake_minimum_required(VERSION 3.25)

project(porta VERSION 0.1.0 LANGUAGES CXX)

include(GNUInstallDirs)
include(CMakePackageConfigHelpers)
include(CTest)

set(CMAKE_CXX_STANDARD 23)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

find_package(modulus CONFIG REQUIRED)
find_package(Boost CONFIG REQUIRED COMPONENTS json)
find_package(libgpiod CONFIG REQUIRED)

add_library(porta
  src/config.cpp
  src/detail/errors.cpp
  src/fake.cpp
  src/gpio.cpp
  src/serial.cpp
)
target_include_directories(porta PUBLIC
  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
  $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
)
target_compile_features(porta PUBLIC cxx_std_23)
target_link_libraries(porta PUBLIC
  modulus::modulus
  Boost::boost
  Boost::json
  libgpiod::gpiod
)
add_library(porta::porta ALIAS porta)

if(BUILD_TESTING)
  add_subdirectory(tests)
endif()

install(TARGETS porta
  EXPORT porta-targets
  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)

install(DIRECTORY include/ DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})

install(EXPORT porta-targets
  NAMESPACE porta::
  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/porta
)

configure_package_config_file(
  ${CMAKE_CURRENT_SOURCE_DIR}/cmake/porta_config.cmake.in
  ${CMAKE_CURRENT_BINARY_DIR}/porta-config.cmake
  INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/porta
)

write_basic_package_version_file(
  ${CMAKE_CURRENT_BINARY_DIR}/porta-config-version.cmake
  VERSION ${PROJECT_VERSION}
  COMPATIBILITY SameMajorVersion
)

install(FILES
  ${CMAKE_CURRENT_BINARY_DIR}/porta-config.cmake
  ${CMAKE_CURRENT_BINARY_DIR}/porta-config-version.cmake
  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/porta
)
