cmake_minimum_required(VERSION 3.25)

project(charta VERSION 0.1.0 LANGUAGES CXX)

include(GNUInstallDirs)
include(CMakePackageConfigHelpers)
include(CTest)

set(CMAKE_CXX_STANDARD 23)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

find_package(modulus CONFIG REQUIRED)
find_package(OpenCV CONFIG REQUIRED COMPONENTS core imgproc imgcodecs)
find_package(vista CONFIG REQUIRED)

add_library(charta
  src/detail/errors.cpp
  src/charta.cpp
)
target_include_directories(charta PUBLIC
  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
  $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
)
target_compile_features(charta PUBLIC cxx_std_23)
target_link_libraries(charta PUBLIC
  modulus::modulus
  ${OpenCV_LIBS}
  vista::vista
)
add_library(charta::charta ALIAS charta)

if(BUILD_TESTING)
  add_subdirectory(tests)
endif()

install(TARGETS charta
  EXPORT charta-targets
  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)

install(DIRECTORY include/ DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})

install(EXPORT charta-targets
  NAMESPACE charta::
  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/charta
)

configure_package_config_file(
  ${CMAKE_CURRENT_SOURCE_DIR}/cmake/charta_config.cmake.in
  ${CMAKE_CURRENT_BINARY_DIR}/charta-config.cmake
  INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/charta
)

write_basic_package_version_file(
  ${CMAKE_CURRENT_BINARY_DIR}/charta-config-version.cmake
  VERSION ${PROJECT_VERSION}
  COMPATIBILITY SameMajorVersion
)

install(FILES
  ${CMAKE_CURRENT_BINARY_DIR}/charta-config.cmake
  ${CMAKE_CURRENT_BINARY_DIR}/charta-config-version.cmake
  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/charta
)
