cmake_minimum_required(VERSION 3.25)

project(axis VERSION 0.1.0 LANGUAGES CXX)

include(GNUInstallDirs)
include(CMakePackageConfigHelpers)
include(CTest)

set(CMAKE_CXX_STANDARD 23)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

find_package(modulus CONFIG REQUIRED)
find_package(Boost CONFIG REQUIRED COMPONENTS json)
find_package(porta CONFIG REQUIRED)

add_library(axis
  src/detail/errors.cpp
  src/config.cpp
  src/protocol.cpp
  src/servo.cpp
)
target_include_directories(axis PUBLIC
  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
  $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
)
target_compile_features(axis PUBLIC cxx_std_23)
target_link_libraries(axis PUBLIC
  modulus::modulus
  Boost::boost
  Boost::json
  porta::porta
)
add_library(axis::axis ALIAS axis)

if(BUILD_TESTING)
  add_subdirectory(tests)
endif()

install(TARGETS axis
  EXPORT axis-targets
  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)

install(DIRECTORY include/ DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})

install(EXPORT axis-targets
  NAMESPACE axis::
  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/axis
)

configure_package_config_file(
  ${CMAKE_CURRENT_SOURCE_DIR}/cmake/axis_config.cmake.in
  ${CMAKE_CURRENT_BINARY_DIR}/axis-config.cmake
  INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/axis
)

write_basic_package_version_file(
  ${CMAKE_CURRENT_BINARY_DIR}/axis-config-version.cmake
  VERSION ${PROJECT_VERSION}
  COMPATIBILITY SameMajorVersion
)

install(FILES
  ${CMAKE_CURRENT_BINARY_DIR}/axis-config.cmake
  ${CMAKE_CURRENT_BINARY_DIR}/axis-config-version.cmake
  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/axis
)
