khodowany
73 lines
1.7 KiB
CMake
Executable File
73 lines
1.7 KiB
CMake
Executable File
cmake_minimum_required(VERSION 3.25)
|
|
|
|
project(noto VERSION 0.1.0 LANGUAGES CXX)
|
|
|
|
include(GNUInstallDirs)
|
|
include(CMakePackageConfigHelpers)
|
|
include(CTest)
|
|
|
|
set(CMAKE_CXX_STANDARD 23)
|
|
set(CMAKE_CXX_STANDARD_REQUIRED ON)
|
|
set(CMAKE_CXX_EXTENSIONS OFF)
|
|
|
|
find_package(modulus CONFIG REQUIRED COMPONENTS boost_json sqlite)
|
|
|
|
add_library(noto
|
|
src/detail/core.cpp
|
|
src/detail/errors.cpp
|
|
src/detail/sql.cpp
|
|
src/connection.cpp
|
|
src/config.cpp
|
|
src/errors.cpp
|
|
src/migration.cpp
|
|
src/schema.cpp
|
|
src/transaction.cpp
|
|
)
|
|
target_include_directories(noto PUBLIC
|
|
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
|
|
$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
|
|
)
|
|
target_compile_features(noto PUBLIC cxx_std_23)
|
|
target_link_libraries(noto PUBLIC
|
|
modulus::modulus
|
|
modulus::boost_json
|
|
modulus::sqlite
|
|
)
|
|
add_library(noto::noto ALIAS noto)
|
|
|
|
if(BUILD_TESTING)
|
|
add_subdirectory(tests)
|
|
endif()
|
|
|
|
install(TARGETS noto
|
|
EXPORT noto-targets
|
|
ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
|
|
LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
|
|
RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
|
|
)
|
|
|
|
install(DIRECTORY include/ DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
|
|
|
|
install(EXPORT noto-targets
|
|
NAMESPACE noto::
|
|
DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/noto
|
|
)
|
|
|
|
configure_package_config_file(
|
|
${CMAKE_CURRENT_SOURCE_DIR}/cmake/noto_config.cmake.in
|
|
${CMAKE_CURRENT_BINARY_DIR}/noto-config.cmake
|
|
INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/noto
|
|
)
|
|
|
|
write_basic_package_version_file(
|
|
${CMAKE_CURRENT_BINARY_DIR}/noto-config-version.cmake
|
|
VERSION ${PROJECT_VERSION}
|
|
COMPATIBILITY SameMajorVersion
|
|
)
|
|
|
|
install(FILES
|
|
${CMAKE_CURRENT_BINARY_DIR}/noto-config.cmake
|
|
${CMAKE_CURRENT_BINARY_DIR}/noto-config-version.cmake
|
|
DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/noto
|
|
)
|